Completa parole per mirc [Archivio] - Azzurra IRC Network Forum

^Norad^

27-07-2005, 06:48

Vi siete trovati anche voi a tentare di completare le parole lunghe con il tasto TAB?
Allora questo mini script fa per voi!

Lo script va inserito nei remote.

Per utillizzarlo vanno aggiungente le parole che più usate ad un file dizionario.txt (che viene creato nella directory di mIRC) semplicemente con CTRL F7 dopo aver scritto la parola nell'editbox di qualunque finestra.

In seguito basterà scrivere le prime lettere della parola e poi premere F7 per averne il completamento.

(Prima versione, fase molto beta)

alias f7 {
set %WRCfraseinput $editbox( $active )
if ((( $left(%WRCPfraseout ,1) == $chr(32) ) && ( %WRCfraseinput != $right( %WRCPfraseout ,-1))) || (( $left(%WRCPfraseout ,1) != $chr(32) ) && ( %WRCfraseinput != %WRCPfraseout ))) {
unset %WRCP*
if ( $len(%WRCfraseinput) < 1 ) halt
else {
set %WRCPspazi $pos(%WRCfraseinput, $chr(32) , 0)
if ( %WRCPspazi != 0 ) {
set %WRCPultimo_spazio $pos(%WRCfraseinput, $chr(32) , %WRCPspazi )
set %WRCPinizioparola $right(%WRCfraseinput,- $+ %WRCPultimo_spazio)
}
else { set %WRCPinizioparola %WRCfraseinput }
set %WRCPiniziofrase $left(%WRCfraseinput,%WRCPultimo_spazio)
}
}
set %WRCPlineadiz %WRCPlineadiz + 1
set %WRCPparolaintera $read( dizionario.txt, w, %WRCPinizioparola $+ *, %WRCPlineadiz )
set %WRCPlineadiz $readn
if ( %WRCPparolaintera != $null ) set %WRCPfraseout %WRCPiniziofrase $+ $chr(32) $+ %WRCPparolaintera
else set %WRCPfraseout %WRCPiniziofrase $+ $chr(32) $+ %WRCPinizioparola
editbox -a %WRCPfraseout
}

alias cf7 {
set %WRCAfraseinput $editbox( $active )
if ( $len(%WRCAfraseinput) < 3 ) halt
else {
set %WRCAspazi $pos(%WRCAfraseinput, $chr(32) , 0)
if ( %WRCAspazi != 0 ) {
set %WRCAultimo_spazio $pos(%WRCAfraseinput, $chr(32) , %WRCAspazi )
set %WRCAparolaaggiuntiva $right(%WRCAfraseinput,- $+ %WRCAultimo_spazio)
}
else { set %WRCAparolaaggiuntiva %WRCAfraseinput }
}
set %WRCAcontrollo $read( dizionario.txt, w, %WRCAparolaaggiuntiva )
if ( $readn == 0 ) {
write dizionario.txt %WRCAparolaaggiuntiva
echo 3 -a *** La parola %WRCAparolaaggiuntiva è stata aggiunta al dizionario
}
else echo 3 -a *** La parola %WRCAparolaaggiuntiva è già nel dizionario
editbox -a
unset %WRCA*
}

:D :D :D :D :D :D :D

^Norad^

11-10-2005, 03:31

Versione riveduta e corretta :D
Il tasto da utilizzare è ora F3, più vicino al tab e quindi più comodo.
Naturalmente è possibile sostituirlo con qualunque tasto funzione, facendo attenzione ad eventuali conflitti con altri script ed evitando il tasto F1, normalmente dedicato all'help

; ###############################################
;
; worcompletion.mrc completa parole per mirc
; ver 2.0
;
; ^Norad^ norad @ azzurra.org
;
; ###############################################
;
; ^^^^^^^^^^^^^^^^^^^^^ HELP ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

;
; Utilizzo dello script:
; Impostazione del file dizionario mediante menu
; Se il file dizionario non esiste viene creato, col nome specificato, al momento dell'inserimento della prima parola
; Inserimento delle parole più usate nel dizionario mediante menu o tasto Ctrl F3
; Completamento delle parole mediante il tasto F3
; Eliminazione di parole sbagliate mediante menu o tasto Shift F3
; Le combinazioni di tasti agiscono sull'ultima parola o inizio di parola nell'editbox della finestra
; Se si utilizza il menu invece, per aggiungere o eliminare parole dal dizionario, queste vanno inserite nella casella popup
;
; Nel menu risultano disponibili i seguenti comandi:
; Dictionary: mostra il dizionario in uso
; Set dictionary...: imposta come dizionario il file specificato
; Add word...: aggiunge la parola specificata al dizionario attivo
; Del word...: elimina la parola specificata dal dizionario attivo
; Editing: se è attivo le parole nell'editbox vengono cancellate dopo l'uso di Ctrl F3 o Shift F3
; se è disattivato l'ultima parola nell'editbox viene aggiunta o tolta dal dizionario,
; ma la frase scritta rimane nell'editbox
;
; Da linea di comando è possibile digitare:
; WRClookdiz : mostra il dizionario in uso
; WRCdizfile [nome dizionario] : imposta come dizionario il file specificato
; WRCadd [parola da aggiungere] : aggiunge la parola specificata al dizionario attivo
; WRCdel [parola da eliminare] : elimina la parola specificata dal dizionario attivo
;
;^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ ^^^^^^^^^^^^^^^^^^^^^^^^^^^^

;
;
;
menu menubar {
Word completion
.Dictionary: WRClookdiz
.Set dictionary...: WRCdizfile
.Add word...: WRCadd
.Del word...: WRCdel
.$iif( %WRCediting,$style(1)) Editing : if (%WRCediting == 1) { unset %WRCediting | echo 3 -a *** Editing disattivato } | else { set %WRCediting 1 | echo 3 -a *** Editing attivo }
}

; **********************
alias WRCdizfile {
if ($1 != $null) set %WRCAdizionario $$1
else set %WRCAdizionario $?="Nome del dizionario da utilizzare: $crlf $+ [dizionario in uso: %WRCdizfile ]"
if ( %WRCAdizionario != $null ) {
if ( $right( %WRCAdizionario ,4) == .txt ) { set %WRCdizfile %WRCAdizionario }
else { set %WRCdizfile %WRCAdizionario $+ .txt }
echo 3 -a *** Il dizionario in uso è ora %WRCdizfile
}
elseif ( %WRCdizfile == $null ) { echo 3 -a *** Nessun dizionario in uso }
else { echo 3 -a *** Il dizionario in uso è %WRCdizfile }
unset %WRCA*
}

;**********************
alias WRClookdiz {
if ( %WRCdizfile != $null ) { echo 3 -a *** Il dizionario in uso è %WRCdizfile }
else { echo 3 -a *** Nessun dizionario attivo }
}
; **********************
alias f3 {
if ( %WRCdizfile == $null ) { echo 3 -a *** Nessun dizionario attivo | halt }

set %WRCfraseinput $editbox( $active )
if ((( $left(%WRCPfraseout ,1) == $chr(32) ) && ( %WRCfraseinput != $right( %WRCPfraseout ,-1))) || (( $left(%WRCPfraseout ,1) != $chr(32) ) && ( %WRCfraseinput != %WRCPfraseout ))) {
unset %WRCP*
if ( $len(%WRCfraseinput) < 1 ) halt
else {
set %WRCPspazi $pos(%WRCfraseinput, $chr(32) , 0)
if ( %WRCPspazi != 0 ) {
set %WRCPultimo_spazio $pos(%WRCfraseinput, $chr(32) , %WRCPspazi )
set %WRCPinizioparola $right(%WRCfraseinput,- $+ %WRCPultimo_spazio)
}
else { set %WRCPinizioparola %WRCfraseinput }
set %WRCPiniziofrase $left(%WRCfraseinput,%WRCPultimo_spazio)
}
}
set %WRCPlineadiz %WRCPlineadiz + 1
set %WRCPparolaintera $read( %WRCdizfile , w, %WRCPinizioparola $+ *, %WRCPlineadiz )
set %WRCPlineadiz $readn
if ( %WRCPparolaintera != $null ) set %WRCPfraseout %WRCPiniziofrase $+ $chr(32) $+ %WRCPparolaintera
else set %WRCPfraseout %WRCPiniziofrase $+ $chr(32) $+ %WRCPinizioparola
editbox -a %WRCPfraseout
}

; **********************
alias cf3 {
if ( %WRCdizfile == $null ) { echo 3 -a *** Nessun dizionario attivo | halt }
set %WRCAfraseinput $editbox( $active )
if ( $len(%WRCAfraseinput) < 4 ) halt
else {
set %WRCAspazi $pos(%WRCAfraseinput, $chr(32) , 0)
if ( %WRCAspazi != 0 ) {
set %WRCAultimo_spazio $pos(%WRCAfraseinput, $chr(32) , %WRCAspazi )
set %WRCAparolaaggiuntiva $right(%WRCAfraseinput,- $+ %WRCAultimo_spazio)
}
else { set %WRCAparolaaggiuntiva %WRCAfraseinput }
}
set %WRCAcontrollo $read( %WRCdizfile , w, %WRCAparolaaggiuntiva )
if ( $readn == 0 ) {
write %WRCdizfile %WRCAparolaaggiuntiva
echo 3 -a *** La parola %WRCAparolaaggiuntiva è stata aggiunta al dizionario
}
else echo 3 -a *** La parola %WRCAparolaaggiuntiva è già nel dizionario
if ( %WRCediting == ON ) editbox -a
unset %WRCA*
}

; **********************
alias sf3 {
if ( %WRCdizfile == $null ) { echo 3 -a *** Nessun dizionario attivo | halt }
set %WRCAfraseinput $editbox( $active )

set %WRCAspazi $pos(%WRCAfraseinput, $chr(32) , 0)
if ( %WRCAspazi != 0 ) {
set %WRCAultimo_spazio $pos(%WRCAfraseinput, $chr(32) , %WRCAspazi )
set %WRCAparoladatogliere $right(%WRCAfraseinput,- $+ %WRCAultimo_spazio)
}
else { set %WRCAparoladatogliere %WRCAfraseinput }

set %WRCAcontrollo $read( %WRCdizfile , w, %WRCAparoladatogliere )
if ( $readn != 0 ) {
/write -dl $+ $readn %WRCdizfile %WRCAparoladatogliere
echo 3 -a *** La parola %WRCAparoladatogliere è stata eliminata dal dizionario
}
else echo 3 -a *** La parola %WRCAparoladatogliere non è nel dizionario
if ( %WRCediting == ON ) editbox -a
unset %WRCA*
}

; **********************
alias WRCadd {
if ( %WRCdizfile == $null ) { echo 3 -a *** Nessun dizionario attivo | halt }
if ($1 != $null) set %WRCAparolaaggiuntiva $$1
else set %WRCAparolaaggiuntiva $$?="Parola da aggiungere al dizionario"
set %WRCAcontrollo $read( %WRCdizfile , w, %WRCAparolaaggiuntiva )
if ( $readn == 0 ) {
write %WRCdizfile %WRCAparolaaggiuntiva
echo 3 -a *** La parola %WRCAparolaaggiuntiva è stata aggiunta al dizionario
}
else echo 3 -a *** La parola %WRCAparolaaggiuntiva è già nel dizionario
unset %WRCA*
}

; **********************
alias WRCdel {
if ( %WRCdizfile == $null ) { echo 3 -a *** Nessun dizionario attivo | halt }
if ($1 != $null) set %WRCAparoladatogliere $$1
else set %WRCAparoladatogliere $$?="Parola da eliminare dal dizionario"
set %WRCAcontrollo $read( %WRCdizfile , w, %WRCAparoladatogliere )
if ( $readn != 0 ) {
/write -dl $+ $readn %WRCdizfile %WRCAparoladatogliere
echo 3 -a *** La parola %WRCAparoladatogliere è stata eliminata dal dizionario
}
else echo 3 -a *** La parola %WRCAparoladatogliere non è nel dizionario
unset %WRCA*
}